divz
Prev | Orchestra Opcodes and Operators | Next

## divz

divz — Safely divides two numbers.

## Syntax

    ares divz xa, xb, ksubst

    ires divz ia, ib, isubst

    kres divz ka, kb, ksubst

    ...divz(ka, kb, ksubst)... (no rate restriction)

## Description

Safely divides two numbers.

## Initialization

Whenever b is not zero, set the result to the value a / b; when b is zero, set it to the value of subst instead.

## Examples

Here is an example of the divz opcode. It uses the file divz.csd.

Example 224. Example of the divz opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o divz.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Define the numbers to be divided.
      ka init 200
      ; Linearly change the value of kb from 200 to 0.
      kb line 0, p3, 200
      ; If a "divide by zero" error occurs, substitute -1.
      ksubst init -1

      ; Safely divide the numbers.
      kresults divz ka, kb, ksubst

      ; Print out the results.
      printks "%f / %f = %f\\n", 0.1, ka, kb, kresults
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for one second.
    i 1 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like:

    200.000000 / 0.000000 = -1.000000
    200.000000 / 19.999887 = 10.000056
    200.000000 / 40.000027 = 4.999997

## See Also

=, init, tival

## Credits

Author: John ffitch after an idea by Barry L. Vercoe

Example written by Kevin Conder.

Functional form available in csound Version 6.00

Prev | Up | Next
distort1 | Home | doppler