fmwurlie
Prev | Orchestra Opcodes and Operators | Next

## fmwurlie

fmwurlie — Uses FM synthesis to create a Wurlitzer electric piano sound.

## Description

Uses FM synthesis to create a Wurlitzer electric piano sound. It comes from a family of FM sounds, all using 4 basic oscillators and various architectures, as used in the TX81Z synthesizer.

## Syntax

    ares fmwurlie kamp, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, \
          ifn4, ivfn

## Initialization

All these opcodes take 5 tables for initialization. The first 4 are the basic inputs and the last is the low frequency oscillator (LFO) used for vibrato. The last table should usually be a sine wave.

The initial waves should be:

- ifn1 -- sine wave

- ifn2 -- sine wave

- ifn3 -- sine wave

- ifn4 -- fwavblnk.aiff

| Note
The file “fwavblnk.aiff” is also available at ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

## Performance

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

kc1, kc2 -- Controls for the synthesizer:

- kc1 -- Mod index 1

- kc2 -- Crossfade of two outputs

- Algorithm -- 5

kvdepth -- Vibrator depth

kvrate -- Vibrator rate

## Examples

Here is an example of the fmwurlie opcode. It uses the file fmwurlie.csd, and fwavblnk.aiff.

Example 339. Example of the fmwurlie opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o fmwurlie.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kfreq = 440
    kc1 = p4
    kc2 = 1
    kvdepth = 0.05
    kvrate = 6
    ifn1 = 1
    ifn2 = 1
    ifn3 = 1
    ifn4 = 2
    ivfn = 1

    asig fmwurlie .5, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, ifn4, ivfn
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; sine wave
    f 1 0 32768 10 1
    ; audio file
    f 2 0 256 1 "fwavblnk.aiff" 0 0 0

    i 1 0 3 6
    i 1 + 3 30
    i 1 + 2 60
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

fmb3, fmbell, fmmetal, fmpercfl, fmrhode

## Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 3.47

Prev | Up | Next
fmvoice | Home | fof