dbfsamp
Prev | Orchestra Opcodes and Operators | Next

## dbfsamp

dbfsamp — Returns the decibel equivalent of the raw amplitude x, relative to full scale amplitude.

## Description

Returns the decibel equivalent of the raw amplitude x, relative to full scale amplitude. Full scale is assumed to be 16 bit. New is Csound version 4.10.

## Syntax

    dbfsamp(x)  (init-rate or control-rate args only)

## Examples

Here is an example of the dbfsamp opcode. It uses the file dbfsamp.csd.

Example 189. Example of the dbfsamp opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o dbfsamp.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    instr 1

    iamp = p4
    idb  = dbfsamp(iamp)
         print idb
    asig vco2 iamp, 110	;sawtooth
         outs asig, asig

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1 1
    i 1 + 1 100
    i 1 + 1 1000
    i 1 + 1 10000
    i 1 + 1 30000
    e

    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like this:

    instr 1:  idb = -90.309
    instr 1:  idb = -50.309
    instr 1:  idb = -30.309
    instr 1:  idb = -10.309
    instr 1:  idb = -0.767

## See Also

ampdb, ampdbfs, dbamp

Prev | Up | Next
dbamp | Home | dcblock