print
Prev | Orchestra Opcodes and Operators | Next

## print

print — Displays the values init (i-rate) variables.

## Description

These units will print orchestra init-values.

## Syntax

    print iarg [, iarg1] [, iarg2] [...]

## Initialization

iarg, iarg2, ... -- i-rate arguments.

## Performance

print -- print the current value of the i-time arguments (or expressions) iarg at every i-pass through the instrument.

| Note
The print opcode will truncate decimal places and may not show the complete value. Csound's precision depends on whether it is the floats (32-bit) or double (64-bit) version, since most internal calculations use one of these formats. If you need more resolution in the console output, you can try printf.

## Examples

Here is an example of the print opcode. It uses the file print.csd.

Example 731. Example of the print opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o print.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    irand = rnd(3)			;generate a random number from 0 to 3
    print irand			;print it
    asig  poscil .7, 440*irand, 1
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 16384 10 1	;sine wave

    i 1 0 1
    i 1 2 1
    i 1 4 1
    e
    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like these:

    instr 1:  irand = 2.930
    instr 1:  irand = 0.420
    instr 1:  irand = 2.316

## See Also

dispfft, display, printk, printk2, printks , printf and prints

Prev | Up | Next
prepiano | Home | printf