midinoteoff
Prev | Orchestra Opcodes and Operators | Next

## midinoteoff

midinoteoff — Gets a MIDI noteoff value.

## Description

midinoteoff is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

## Syntax

    midinoteoff xkey, xvelocity

## Performance

xkey -- returns MIDI key during MIDI activation, remains unchanged otherwise.

xvelocity -- returns MIDI velocity during MIDI activation, remains unchanged otherwise.

If the instrument was activated by MIDI input, the opcode overwrites the values of the xkey and xvelocity with the corresponding values from MIDI input. If the instrument was NOT activated by MIDI input, the values of xkey and xvelocity remain unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

| Adapting a score-activated Csound instrument.
See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

## Examples

Here is an example of the midinoteoff opcode. It uses the file midinoteoff.csd.

Example 558. Example of the midinoteoff opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    -M1 -Q1  ;;;realtime audio out and midi in and midi out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o midinoteoff.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1	;uses external midi device

    kkey init 0				;initialize key number
    kvel init 0				;initialize velocity
    midinoteoff kkey,kvel			;MIDI noteoff value
    printk2	kvel				;display noteoff value
    midion 1, kkey, kvel			;sent note to external device

    endin
    </CsInstruments>
    <CsScore>
    f 0 30	;runs for 30 seconds

    i 1 0 2 62	; play these notes from score as well
    i 1 + 2 65
    e
    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like:

     i1    60.00000
     i1    76.00000

## See Also

midichannelaftertouch, midicontrolchange, mididefault, midinoteoncps, midinoteonkey, midinoteonoct, midinoteonpch, midipitchbend, midipolyaftertouch, midiprogramchange

## Credits

Author: Michael Gogins

New in version 4.20

Prev | Up | Next
midifilestatus | Home | midinoteoncps